cara membuat kata sandi di blog

Membuat halaman yang dilindungi sandi

Membuat halaman logon yang terlihat mirip untuk logon Windows khas kotak dialog. Pengguna yang mencoba untuk mengakses halaman Web dilindungi password dikirim ke Halaman ini untuk mengetik nama pengguna dan sandi. Untuk membuat halaman logon, ikuti langkah-langkah berikut:

Di FrontPage 2003, klik Berkas, klik Baru, lalu klik Halaman kosong.
Di daerah footer jendela dokumen, klikKode untuk menunjukkan tampilan kode.
Memilih dan kemudian menghapus semua kode HTML di Web Halaman.
Ketik atau tempel kode HTML berikut di halaman Web.

<% @language="vbscript" %>
<!--#include virtual="/logon/_private/logon.inc"-->
<%
  ' Was this page posted to?
  If UCase(Request.ServerVariables("HTTP_METHOD")) = "POST" Then
    ' If so, check the username/password that was entered.
    If ComparePassword(Request("UID"),Request("PWD")) Then
      ' If comparison was good, store the user name...
      Session("UID") = Request("UID")
      ' ...and redirect back to the original page.
      Response.Redirect Session("REFERRER")
    End If
  End If
%>
<html>
<head><title>Logon Page</title>
<style>
body  { font-family: arial, helvetica }
table { background-color: #cccccc; font-size: 9pt; padding: 3px }
td    { color: #000000; background-color: #cccccc; border-width: 0px }
th    { color: #ffffff; background-color: #0000cc; border-width: 0px }
</style>
</head>
<body bgcolor="#000000" text="#ffffff">
<h3 align="center">&#xa0;</h3>
<div align="center"><center>
<form action="<%=LOGON_PAGE%>" method="POST">
<table border="2" cellpadding="2" cellspacing="2">
  <tr>
    <th colspan="4" align="left">Enter User Name and Password</th>
  </tr>
  <tr>
    <td>&#xa0;</td>
    <td colspan="2" align="left">Please type your user name and password.</td>
    <td>&#xa0;</td>
  </tr>
  <tr>
    <td>&#xa0;</td>
    <td align="left">Site</td>
    <td align="left"><%=Request.ServerVariables("SERVER_NAME")%> &#xa0;</td>
    <td>&#xa0;</td>
  </tr>
  <tr>
    <td>&#xa0;</td>
    <td align="left">User Name</td>
    <td align="left"><input name="UID" type="text" size="20"></td>
    <td>&#xa0;</td>
  </tr>
  <tr>
    <td>&#xa0;</td>
    <td align="left">Password</td>
    <td align="left"><input name="PWD" type="password" size="20"></td>
    <td>&#xa0;</td>
  </tr>
  <tr>
    <td>&#xa0;</td>
    <td colspan="2" align="center"><input type="submit" value="LOGON"></td>
    <td>&#xa0;</td>
  </tr>
</table>
</form>
</center></div>
</body>
</html>

Klik kanan new_page_1.htm tab, dan kemudian klik Simpan.

Save page as logon.asp di root folder dari situs Web Anda logon.
Pada Berkas menu, klikTutup untuk menutup halaman Web logon.asp.

Membuat logon termasuk file

Termasuk file menyediakan fungsionalitas nama dan sandi pengguna dan digunakan oleh halaman Web yang dilindungi sandi dan halaman Web logon. Pada membuat logon termasuk berkas, ikuti langkah berikut:

Di FrontPage 2003, klik Berkas, klik Baru, lalu klik Halaman kosong.
Di daerah footer jendela dokumen, klikKode untuk menunjukkan tampilan kode.
Memilih dan kemudian menghapus semua kode HTML di Web Halaman.

Ketik atau tempel kode HTML berikut di halaman Web.

<%
  ' Do not cache this page.
  Response.CacheControl = "no-cache"

  ' Define the name of the users table.
  Const USERS_TABLE  = "tblUsers"
  ' Define the path to the logon page.
  Const LOGON_PAGE   = "/logon/logon.asp"
  ' Define the path to the logon database.
  Const MDB_URL      = "/logon/_private/logon.mdb"

  ' Check to see whether you have a current user name.
  If Len(Session("UID")) = 0 Then
    ' Are you currently on the logon page?
    If LCase(LOGON_PAGE) <> LCase(Request.ServerVariables("URL")) Then
      ' If not, set a session variable for the page that made the request...
      Session("REFERRER") = Request.ServerVariables("URL")
      ' ...and redirect to the logon page.
      Response.Redirect LOGON_PAGE
    End If
  End If

  ' This function checks for a username/password combination.
  Function ComparePassword(UID,PWD)
    ' Define your variables.
    Dim strSQL, objCN, objRS
    ' Set up your SQL string.
    strSQL = "SELECT * FROM " & USERS_TABLE & _
      " WHERE (UID='" & ParseText(UID) & _
      "' AND PWD='" & ParseText(PWD) & "');"
    ' Create a database connection object.
    Set objCN = Server.CreateObject("ADODB.Connection")
    ' Open the database connection object.
    objCN.Open "driver={Microsoft Access Driver (*.mdb)}; dbq=" & _
      Server.MapPath(MDB_URL) & "; uid=admin; pwd="
    ' Run the database query.
    Set objRS = objCN.Execute(strSQL)
    ' Set the status to true/false for the database lookup.
    ComparePassword = Not(objRS.EOF)
    ' Close your database objects.
    Set objRS = Nothing
    Set objCN = Nothing
  End Function

  ' This function restricts text to alpha-numeric data only.
  Function ParseText(TXT)
    Dim intPos, strText, intText
    For intPos = 1 TO Len(TXT)
      intText = Asc(Mid(TXT,intPos,1))
      If (intText > 47 And intText < 58) Or _
         (intText > 64 And intText < 91) Or _
         (intText > 96 And intText < 123) Then
          strText = strText & Mid(TXT,intPos,1)
      End if
    Next
    ParseText = strText
  End Function
%>

Klik kanan new_page_1.htm tab, dan kemudian klik Simpan.

Save page as logon.Inc dalam _private folder dari situs Web Anda logon.
Pada Berkas menu, klikTutup untuk menutup berkas logon.inc.

Menguji situs Web logon

Untuk melakukannya, ikuti langkah-langkah berikut:

Di FrontPage 2003, di Daftar folderpanel, klik kanan Default.asp, lalu klik Pratinjau dalam Browser.

Web browser load halaman rumah sampel dan menunjukkan bahwa Anda tidak logon.
Klik Nonsecure Halaman link.

Halaman beban dan menunjukkan bahwa Anda tidak logon. Klik Kembali ke default link untuk kembali ke halaman default.
Klik Halaman yang dilindungi sandi link.

Logon.asp halaman load bukannya dilindungi sandi Halaman.
Dalam Nama pengguna kotak, jenistestuser, jenis sandi dalamSandi kotak, dan kemudian klik MASUK.

Halaman yang dilindungi sandi muncul dan menunjukkan bahwa Anda logon sebagai testuser. Klik Kembali ke defaultlink untuk kembali ke Halaman default. Home page load dan menunjukkan bahwa Anda logon sebagai testuser.
Klik Nonsecure Halaman link.

Halaman beban dan menunjukkan bahwa Anda logon sebagai testuser.

Menyesuaikan situs Web logon

Anda dapat menyesuaikan situs Web contoh logon berikut cara:

Menambahkan nama pengguna dan password: Anda dapat membuka database. Pada Jadi, klik dua kali database di FrontPage 2003, dan kemudian menambahkan pengguna untuk tblUsers tabel.
Password melindungi halaman Web lain: untuk melindungi sandi Halaman Web lain di situs Web Anda, Anda harus menyimpan berkas dengan nama file ASP ekstensi, misalnya, Mypage.asp, dan kemudian tambahkan dua baris berikut ke puncak file:
<% @language="vbscript" %> 
Baris pertama menunjukkan bahwa Anda menggunakan Microsoft Visual Basic Scripting Edition (VBScript) untuk Anda dan bahasa skrip, baris kedua termasuk pengguna nama dan sandi fungsionalitas dari logon termasuk file yang Anda buat sebelumnya.

semoga para blogger terbantu dengan artikel saya ini

Tantom-angkola : cara membuat kata sandi di blog
tantom angkola berdiri sejak tahun 2012 : Membuat halaman yang dilindungi sandi Membuat halaman logon yang terlihat mirip untuk logon Windows khas kotak dialog. Pengguna yang menco...